STATA-FORUM.DE

[Kathi00]

Hallo Leute,

ich bin ein Neuling was STATA angeht und hoffe, dass Ihr mir helfen könnt.

Folgendes Problem: Ich habe eine Tabelle mit den Umsätzen verschiedener Firmen in verschiedenen Jahren. Ich muss jetzt herausfinden wie oft der Umsatz im Vergleich zum vorherigen Jahr zurückgegangen ist, d.h. Umsatz t < Umsatz t-1.

Ich habe schon versucht eine neue Variable zu generieren, die die Veränderung zum Vorjahr wiedergibt. Aber leider war da wohl ein Fehler drin, weil das Ergebnis nicht stimmen konnte, wenn ich es mal stichprobenartig manuell geprüft habe.

Vielleicht hat jemand von euch eine Idee, wie man da heran gehen könnte?

Viele Grüße und vielen Danke.

Kathi00

[daniel]

Kannst Du ein replizierbares Minimalbeispiel zeigen?

(add-ons-und-ado-files-f20/beispieldatensatze-erzeugen-t232.html)

[Kathi00]

Hallo Daniel,

das ist ein Auszug aus meinem Datensatz:

fyear sale firm
1983 25.395 5812
1984 32.007 5812
1985 53.798 5812
1983 13.793 5712
1984 13.829 5712
1985 24.189 5712
1986 36.308 5712
1987 37.356 5712
1988 32.808 5712
1978 118.667 5080
1979 130.617 5080
1980 132.482 5080
1981 175.924 5080
1982 155.006 5080
1983 177.762 5080
1984 218.946 5080
1985 248.012 5080
1986 298.192 5080
1987 347.64 5080
1988 406.36 5080
1989 444.875 5080
1990 466.542 5080
1991 422.657 5080
1992 382.78 5080
1993 407.754 5080
1994 451.395 5080
1995 504.99 5080
1996 589.328 5080
1997 782.1230000000001 5080

Ich hoffe es hilft. Und danke schonmal fürs anschauen.

[daniel]

Hier ein Beispiel

Code: Alles auswählen

// create toy data

clear
inp fyear   sale   firm
1983   25.395   5812
1984   32.007   5812
1985   53.798   5812
1983   13.793   5712
1984   13.829   5712
1985   24.189   5712
1986   36.308   5712
1987   37.356   5712
1988   32.808   5712
1978   118.667   5080
1979   130.617   5080
1980   132.482   5080
1981   175.924   5080
1982   155.006   5080
1983   177.762   5080
1984   218.946   5080
1985   248.012   5080
1986   298.192   5080
1987   347.64   5080
1988   406.36   5080
1989   444.875   5080
1990   466.542   5080
1991   422.657   5080
1992   382.78   5080
1993   407.754   5080
1994   451.395   5080
1995   504.99   5080
1996   589.328   5080
1997   782.1230000000001   5080
end

l ,sepby(firm)

// declare dataset as a panel
xtset firm fyear

// now calculate first differences for sale
g sale_diff = D.sale

l ,sepby(firm)

// create an indicator marking negative differences
g negative = (sale_diff < 0)

l ,sepby(firm)

// now count the 1's by firm
bys firm : cou if negative

// you can hold this in a variable
bys firm (fyear) : g sum_neg = sum(negative)
bys firm (fyear) : replace sum_neg = sum_neg[_N]

l ,sepby(firm)


[Kathi00]

Hallo,

Danke schonmal. Bei meinem längeren Datensatz kommt folgende Fehlermeldung für den command xtset: repeated time values within panel.
Wie kann ich das beheben? Ich habe schon versucht zu googeln, aber leider nichts nützliches gefunden...

Viele Grüße

[daniel]

Sieh das nicht als schlichtes "technisches" Problem! Zu glauben Fehlermeldungen seien immer technischer Natur, ist ein weit verbreiteter Irrtum. Noch viel schlimmer (weil weitaus gefährlicher) ist die Annahme, das Ausbleiben einer Fehlermeldung sei Garant dafür, dass inhaltlich alles einwandfrei sei.

Stata macht Dich darauf aufmerksam, dass Du für ein und dieselbe Firma in ein und dem selben Jahr mehrere Umsätze beobachtet hast. Wie kann das theoretisch sein? Was willst Du in einem solchen Fall theoretisch tun?

help isid
help duplicates

können helfen, die "Problemfälle" zu finden.